CONTINUOUS_MODEL EnvLeak

ABSTRACT "The model EnvLeak is obsolete and should be replaced with CeLeak.

A powerlaw leak model between zone and environment.
Bidirectional transports of mass, energy, a mass fraction and humidity.
Leak also acts as a conductive cold bridge between interior and environment.

990216 MV  rho back wo event
980503 PS  High limits for x_in and x_out
980318 MV  Event is temporarily moved from rho calculation
971204 MV  More corrections to density calculation
           comment introduced here by AB 971210
971203 AB  dp0 default changed to 0.01
971125 MV  density calculation is changed
970520 PS  Redundant parameter cp removed.
970523 PS  Outside link renamed to Ambient
970604 AB  Added LOC enthalpy HLeak
9708?  ?   Removed CP as parameter.
"

EQUATIONS

/*driving pressure difference*/

Rho_in := RHOMOIS (T_in,Hum_in);
Rho_out := RHOMOIS (T_out,Hum_out);

Dp := P_in - Rho_in*G*zr_in - (P_out - Rho_out*G*zr_out)-Rho*G*dz; 

/* powerlaw massflow equation */
  M  = IF LINEARIZE (1) THEN c * Dp
       ELSE_IF abs (Dp) < dp0 THEN c0 * Dp
       ELSE_IF Dp > 0 THEN c * Dp**n
       ELSE -c * (-Dp)**n
       END_IF 
  BAD_INVERSES () ;

/* convected and conducted heat through leak */
   HLeak := IF M > 0.0 THEN
              Enthal(T_in,Hum_In)
            ELSE
              Enthal(T_out,Hum_Out)
            END_IF;

   Q = IF LINEARIZE (1) THEN (T_in - T_out) / 2
       ELSE HLeak * M
       END_IF
      /* + conduction*/
      + uaBridge*(T_in - T_out)
  GOOD_INVERSES (Q) ;

/* fraction transported through leak*/
  Xf = IF LINEARIZE (1) THEN (X_in - X_out) / 2
       ELSE_IF M > 0.0 THEN X_in * M
       ELSE X_out * M
       END_IF 
  GOOD_INVERSES (Xf);

/* moisture transported through leak*/
  Humf = IF LINEARIZE (1) THEN (Hum_in - Hum_out) / 2
         ELSE_IF M > 0.0 THEN Hum_in * M
         ELSE Hum_out * M
         END_IF 
  GOOD_INVERSES (Humf);

/* density of crack air is (was) an assigned state (due to hysteresis) */
  Rho := IF M > 0 THEN
           rho_in
         ELSE
           rho_out
         END_IF ;

/*
  Rho := IF EVENT(Mm, M) > 0 THEN
           rho_in
         ELSE
           rho_out
         END_IF ;
  Rho := rho_20;
*/

LINKS
                                   
/* type  name    variables... */ 

BidirAir Inside  P_in, POS_IN  M, T_in, POS_IN  Q,
                 X_in, POS_IN  Xf,Hum_in, POS_IN Humf;
BidirAir Ambient P_out, POS_OUT M, T_out,POS_OUT Q,
                 X_out,POS_OUT Xf,Hum_out, POS_OUT Humf;




VARIABLES

/* type    name     role def  min    max  description */
  
Density      Rho     A_S     1.2         .5      3  "density of leak air"
Density      Rho_in  LOC     1.2         .5      3  "density of zone air"
Density      Rho_out LOC     1.2         .5      3  "density of outside air"
MassFlow     M       OUT    -0.002     -BIG    BIG  "massflow through leak"
MassFlow     Mm      A_S    -0.002     -BIG    BIG  "massflow memory"
Pressure     P_in    IN   1310         -BIG    BIG  "inside floor pressure"
Pressure     P_out   IN   1325         -BIG    BIG  "outside grnd pressure"
Temp         T_in    IN     25     ABS_ZERO    BIG  "inside temperature"
Temp         T_out   IN     20     ABS_ZERO    BIG  "outside temperature"
Enthalpy     HLeak   LOC 40000         -BIG    BIG  "enthalpy of leak air"
HeatFlux     Q       OUT   -80         -BIG    BIG  "heat moved by massflow"
Fraction_y   X_in    IN    594            0    BIG  "zone fraction"
Fraction_y   X_out   IN    594            0    BIG  "environment fraction"
FractFlow_y  Xf      OUT     0         -BIG    BIG  "fraction moved"
HumRatio     Hum_in  IN      .006     SMALL      1  "zone hum"
HumRatio     Hum_out IN      .006     SMALL      1  "environment hum"
HumFlow      Humf    OUT    0          -BIG    BIG  "fraction hum"
Pressure     Dp      LOC   15          -BIG    BIG  "effective pressure diff"


PARAMETERS

/* type    name    role def  min max  description */

/* easy access parameters */
/* priority order: ela, c_t */

Generic    c_t     S_P  1    0   BIG  "powerlaw coeff [kg/(s Pa**n)]"
Generic    n       S_P  .5   .5  1.0  "powerlaw exponent [dimless]"
Area       ela     S_P  0    0   BIG  "equivalent leakage area
                                        at Dp=4 Pa (C_d = 1)"
HeatCond   uaBridge S_P  0    0   BIG  "UA-value for conductive cold bridge"
length     dz      S_P  0  -BIG  BIG  "rise fr in to out (may be <0)"
length     zr_in   S_P  0    0   BIG  "leak height from floor zone"
Length     za_in   S_P  0  -BIG  BIG  "absolute floor level of zone"
Pressure   dp0     S_P  .01 SMALL BIG "limit for linear flow"
Density    rho_20  S_P  1.2 SMALL 1.3 "density at ground pressure"

/* derived parameters */

Generic    c       C_P                "powerlaw coefficient
                                        [kg/(s Pa**n)]"
Generic    c0      C_P                "linear coefficient"
Length     zr_out  C_P                "leak height from ground level"

PARAMETER_PROCESSING
  zr_out := za_in + zr_in + dz;

  c := IF ela > 1E-6 THEN
          ela * SQRT(4 * 2 * rho_20)/4**n
       ELSE
          c_t
       END_IF ;

  c0 := c * dp0**(n-1) ;

END_MODEL