CONTINUOUS_MODEL MixBxCtr


ABSTRACT  "Recirculating MIXing BoX w ConTRol.

           This mixing box model is link-compatible with ICE secondary models.

           The model has a built-in control.

           The minimun fresh air flow is given as a parameter but is also
           controlled by a time schedule.

           Model takes account of possible condensation in the mixing process.

              MFresh   --->   --->  MSup        ----
              TSupIn        ^       TSupOut   |
                            |                 |
                          MReturn             | Zone
                          TExh                |
                            |                 |
              MExhOut  <---   <---  MExh        ----
              TExh                  TExh


Date:      July, 1998

By:        Mika Vuolle 
           
Call:      Enthal   from Psychro1.nmf
           HumRat   from Psychro2.nmf
           SatPres  from Psychro3.nmf

Revision:

010320 MV  QActual is inserted for logging purposes

001211 AB  Limit X effectively to (0.001,0.999)

001127 AB  Limit MFreshMin by MSup

990420 MV  ver 1.1 the On and Cap modes are introduced
           C02 control is added
"



EQUATIONS

  MFreshMin  := min(MFreshOn * MFreshPar, 0.999*MSup);
  MReturnMax := MSup - MFreshMin;

  HSupIn := Enthal(TSupIn,WSupIn);
  HExh   := Enthal(TExh,WExh);

/* Control part */
  WSupCtr := (MFreshMin * WSupIn +
              X * MReturnMax * WExh + (1-X) * MReturnMax * WSupIn) / MSup;

  X = IF On < 0.5 THEN 
        0.001
      ELSE_IF Cap > 0.5 THEN
        0.999
      ELSE
        (MSup * Enthal(TSet,MIN(WSupCtr,HumRat(PSup + 1E5, SatPres(TSet)))) -
         MFreshMin  * HSupIn - MReturnMax * HSupIn) /
        (MReturnMax * HExh - MReturnMax * HSupIn)
      END_IF;


/* Air mass balances */
  MReturn := MIN(1.0,X) * MReturnMax;
  MFresh   = MSup - MReturn;
  MExh     = MReturn + MExhOut;

/* Energy balance */
  MSup * Enthal(TSupOut,WSupOut) = MFresh * HSupIn + MReturn * HExh;

/* Moisture balance */
  WSupMax := HumRat(PSup + 1E5, SatPres(TSupOut));
  WSupOut  = MIN((MReturn*WExh+MFresh*WSupIn)/MSup,WSupMax);
           
/* Fraction balance */
  MSup * XSupOut = MFresh * XSupIn + MReturn * XExh;


/* Postprocessing */

  QActual := MSup * Enthal(TSupOut,WSupOut) - MFresh * HSupIn;


/* Modes */

  On := IF Event(G0, (TSupIn-TSet) * (TExh-TSupIn)) < 0 THEN
          1
        ELSE
          0
        END_IF;

  Cap :=IF Event(G1, (TExh-TSet) * (TSupIn-TExh)) < 0 THEN
          0
        ELSE
          1
        END_IF;


LINKS

/* type      name           variables ....  */

   UniAir    SupIn         PSup, POS_IN  MFresh, TSupIn,  XSupIn,  WSupIn; 
   UniAir    SupOut        PSup, POS_OUT MSup,   TSupOut, XSupOut, WSupOut;

   UniAir    ExhIn         PExh, POS_IN  MExh,    TExh, XExh, WExh; 
   UniAir    ExhOut        PExh, POS_OUT MExhOut, TExh, XExh, WExh;



   T         TempSetPoint  TSet; /*leaving air dry bulb temperature setpoint*/

   Z         FreshOn       MFreshOn;



VARIABLES

/* type      name         role   def          min      max   description*/

   Pressure   PSup        IN    1325         -BIG      BIG   "Pressure of entering and leaving
                                                              supply air"
   Pressure   PExh        IN    1325         -BIG      BIG   "Pressure of entering and leaving
                                                              exhaust air"

   MassFlow   MSup        IN       3.2          0      BIG   "Supply air massflow rate"
   MassFlow   MReturnMax  LOC      3.2          0      BIG   "Max return air massflow rate"
   MassFlow   MFreshMin   LOC      3.2          0      BIG   "Min fresh air massflow rate"
   MassFlow   MFresh      OUT      3.2          0      BIG   "Fresh air massflow rate"

   MassFlow   MExhOut     OUT      3.2          0      BIG   "Outgoing exhaust air massflow rate"
   MassFlow   MExh        IN       3.2          0      BIG   "Incoming exhaust air massflow rate"
   MassFlow   MReturn     LOC      3.2          0      BIG   "Return air massflow rate"

   Enthalpy   HSupIn      LOC  10000         -BIG      BIG   "Incoming supply air enthalpy"
   Enthalpy   HExh        LOC  30000         -BIG      BIG   "Incoming exhaust air enthalpy"

   HeatFlux   Qactual     LOC    100         -BIG      BIG   "Actual heating or cooling power"


   Temp       TSupIn      IN      10     ABS_ZERO      BIG   "Entering supply air temp."
   Temp       TSupOut     OUT     15     ABS_ZERO      BIG   "Leaving supply air temp."
   Temp       TExh        IN      25     ABS_ZERO      BIG   "Entering exhaust air temp."
   Temp       TSet        IN      18     ABS_ZERO      BIG   "Leaving air dry bulb temp. setpoint"

   HumRatio   WSupIn      IN       0.01     SMALL        1   "Humidity ratio of entering supply air"
   HumRatio   WSupOut     OUT      0.01     SMALL        1   "Humidity ratio of leaving supply air"
   HumRatio   WSupMax     LOC      0.01     SMALL        1   "Max humidity ratio of leaving supply air"

   HumRatio   WExh        IN       0.01     SMALL        1   "Humidity ratio of entering exhaust air"

   HumRatio   WSupCtr     LOC      0.01     SMALL        1   "Humidity ratio of control calc."

   Fraction_y XSupIn      IN     594            0      BIG   "Pollutant fraction fresh air"
   Fraction_y XSupOut     OUT    594            0      BIG   "Pollutant fraction supply air"
   Fraction_y XExh        IN     594            0      BIG   "Pollutant fraction exhaust air"

   Factor     MFreshOn    IN       1            0      BIG   "Fresh air multiplier and On / Off"
   Factor     X           OUT      0            0      BIG   "Return air / max return air"


   Generic    On         A_S       1         -BIG      BIG   "Mixbox is on = some return air"
   Generic    Cap        A_S       1         -BIG      BIG   "Full Cap = Max amount of return air"
   Generic    G0         A_S       1         -BIG      BIG   "Memory of mode above"
   Generic    G1         A_S       1         -BIG      BIG   "Memory of mode above"




PARAMETERS

/* type      name         role   def           min     max    description */

   MassFlow  MFreshPar    S_P       3.2          0      BIG   "Dry air supply massflow rate"

END_MODEL