CONTINUOUS_MODEL Elrad

ABSTRACT
 "ELectric RADiator in front of room surface.

  Radiation and convective heat flux flows through the front and the 
  back of a massless radiator.

  In this model, a heat balance calculated for the radiator's back assumes
  100% radiation exchange with the wall behind. Other radiation heat exchange
  is neglected. Convective heat transfer from the radiator's back side and 
  wall is added to zone air.

970527 PS added AirTemp link
"

EQUATIONS


/* Heat exchange at the back of the radiator.
   Convective heat transfer coefficient from 
     Isfält, E., Peterson, F. "Värmeavgivning från radiatorers
     baksida."
     Byggnads-Ingenj/ren 11-12. 1969. pp.40-43,70. (In Swedish). */

   HTCRadBack := HCRAD( TRad, TZone, dSpace, radHeight);
   HTCWall    := HCRAD( Tpa, TZone, dSpace, radHeight);

/* Radiator effekt external control  */
   PRad := PMax*Contr;


/* Convective and long wave heat flow from wall */
   QConvWall = HTCWall * area * (Tpa - TZone) ;

/* Convective and long wave heat flow from radiator back */
   QConvBack = HTCRadBack * area * (TRad - TZone) ;
   QLWBack = eLW * BOLTZ * area * 
             ((TRad - ABS_ZERO)**4 - (Tpa - ABS_ZERO)**4) ;


/* Convected heat from space to zone */
   QRadConv = QConvWall + QConvBack ;

/* Heat balance for wall surface node */

   0 = 	QLWBack - QConvWall - Qa ;

/* Radiator heat balance */
   0 = PRad - QRadFront - QConvBack - QLWBack ;



LINKS
/* type       name         variables   */

   TQ         Front        TRad, POS_OUT QRadFront ;
   TQ         BackConv     TZone, POS_OUT QRadConv ;
   TQ         BackWall     Tpa, POS_OUT  Qa ;
   T          AirTemp      Tzone;

   ControlLink control_in   Contr;

VARIABLES
/* type       name       role  def     min  max    description    */

   Control    Contr      IN    1       0      1    "Radiator power control"
   Temp       TRad       IN   25  ABS_ZERO  BIG    "Radiator temp"
   Temp       Tpa        IN   25  ABS_ZERO  BIG    "Wall exterior surface temp"
   Temp       TZone      IN   25  ABS_ZERO  BIG    "Zone temp entering space"
   HeatFlux   QRadFront  OUT   0      -BIG  BIG    "Heat transfer at radiator 
                                                    front side"
   HeatFlux   Qa         OUT   0      -BIG  BIG    "Influx wall interior side"
   HeatFlux   QLWBack    OUT   0      -BIG  BIG    "Radiative flux behind rad"
   HeatFlux   QConvBack  OUT   0      -BIG  BIG    "Convective flux behind 
                                                    radiator"
   HeatFlux   QConvWall  OUT   0      -BIG  BIG    "Convective flux at wall"
   HeatFlux   QRadConv   OUT   0      -BIG  BIG    "Convective flux to space"

   ElPowerCons PRad       LOC   0       0    BIG    "Radiator effect "

   HeatCondA  HTCRadBack LOC   5       0    BIG    "Heat transfer coefficient at 
                                                    radiator back"
   HeatCondA  HTCWall    LOC   5       0    BIG    "Heat transfer coefficient at 
                                                    wall"

PARAMETERS
/* type       name       role  def     min  max     description    */

/* Radiator */
   Length     radHeight  S_P    .5     0    BIG     "radiator height"
   Length     radWidth   S_P   1       0    BIG     "radiator width"
   Length     dSpace     S_P    .05  SMALL  BIG     "distance between radiator 
                                                     and wall"
   Factor     eLWRad     S_P    .9     0    1.0     "radiator back emissisivity"
   Factor     eLWWall    S_P    .9     0    1.0     "wall long wave 
                                                     emissisivity"
   HeatFlux   PMax       S_P 2000      0    BIG     "Radiator max effect "

/* derived parameters */
   Area       area       C_P   5.    SMALL  BIG     "wall area"
   Factor     eLW        C_P    .8     0    1.0     "long wave emissisivity"

PARAMETER_PROCESSING
   area := radHeight * radWidth ;
   eLW  := 1.0/( 1.0/eLWRad + 1.0/eLWWall - 1.0 ) ;

END_MODEL